HyperPics: Beyond the UI

AutoCAD 2014 API and Developer Documentation Changes

By now, there has been lots of information circulating about what is new in AutoCAD 2014 from an end user perspective but what about the API side of things. AutoCAD 2014 offers a number of API changes, updates to the documentation, and a new API.

First and foremost, AutoCAD 2014 is binary compatible with AutoCAD 2013; programs developed for AutoCAD 2013 should run in AutoCAD 2014 without needing to be recompiled.

JavaScript API

This new API is used to provide the core functionality of the DesignFeed and Live Maps features. What can be done with this new API at the moment is limited, but does open up many new possibilities though. For additional information see:

• JavaScript Reference Guide
• Zooming to an AutoCAD entity using JavaScript - Through the Interface (Kean Walmsley)
• Getting Started with JavaScript API on AutoCAD 2014 - AutoCAD DevBlog (Philippe Leefsma)
• Enabling AutoCAD 2014 JavaScript Debugging - AutoCAD DevBlog (Fenton Webb)

Trusted File Paths

Not just an API change but a security change to which files are automatically loaded and from where they can be loaded from. This change impacts all program file types. There are a few API level changes that you should be aware of, but if your programs are not trusted they do not matter much. So the first things you need to be aware of are the SECURELOAD system variable and the Trusted Locations node on the Files tab of the Options dialog box. For additional information see:

• AutoCAD 2014 and Security - AutoCAD DevBlog (Gopinath Taget)
• AutoCAD 2014 for developers - Through the Interface (Kean Walmsley)

VBA 7.1

Microsoft has recently given new life to the once deprecated VBA technology. VBA 6.3 was the last supported release, which was still being used in AutoCAD 2013 as long as you downloaded the separate installer. VBA 6.3 was 32-bit only and is why there was performance issues when using it with AutoCAD 64-bit. VBA 7.1 resolves this issue by supporting both 32-bit and 64-bit platforms. If you have VBA programs from AutoCAD 2013 or earlier, and you are using Windows 64-bit you might encounter issues if you are using third-party libraries or form controls that do not support 64-bit.  Check with the third-party vendor and see if they offer a 64-bit version for you to use, if not you will need to rework your code and/or forms.

The ActiveX/VBA document has also been updated as well and can be found installed on your local drive at:

• %ProgramFiles%\Common Files\Autodesk Shared\acad_aag.chm - Developer's Guide
• %ProgramFiles%\Common Files\Autodesk Shared\acadauto.chm - Reference Guide

AutoLISP

There were no real notable changes to the API this release or the Visual LISP IDE, with the exception of two new functions.

• showHTMLModalWindow - Displays a modal window with a HTML document; use in conjunction with the new JavaScript API.
• findtrustedfile - Searches the AutoCAD trusted file paths for the specified file.

ObjectARX

Changes to the ObjectARX API are limited to new classes and functions.

• AcDb
  • AcDbExtents2d - New class
  • AcDbGeoDataReactor - New class
  • AcDbModelDocViewStyle - New methods added; existing class
  • AcDbXrecord - New method added; existing class
  • AcDbXrecordIterator - New methods added; existing class
• AcAp
  • AcApDocument - New method added; existing class
• Global functions
  • acedAddHTMLPalette - New
  • acedFindTrustedFile - New
  • acedLoadJSScript - New
  • acedShowHTMLModalWindow - New
  • acedShowHTMLModelessWindow - New
• Miscellaneous class
  • IPointCloudFilter2 - New

Managed .NET

Changes to the Managed .NET API are limited to new classes and functions.

• Autodesk.AutoCAD.ApplicationServices
  • Application.ShowModalWindow Method
  • Application.ShowModelessWindow Method
  • Document.IsNamedDrawing Property
• Autodesk.AutoCAD.DatabaseServices
  • MLeader.Scale Property
  • Region.AreaProperties Method
  • RegionAreaProperties Structure 
  • RegionAreaProperties.Area Property
  • RegionAreaProperties.Centroid Property
  • RegionAreaProperties.Extents Property
  • RegionAreaProperties.MomentsOfInertia Property
  • RegionAreaProperties.Perimeter Property
  • RegionAreaProperties.PrincipalMoments Property
  • RegionAreaProperties.ProductOfInertia Property
  • RegionAreaProperties.RadiiOfGyration Property
  • Xrecord.Append Method
  • XrecordEnumerator.Current Property
  • XrecordEnumerator.InsertAtCurrent Method
  • XrecordEnumerator.RemoveCurrent Method
• Autodesk.AutoCAD.EditorInput
  • Editor.ApplyCurDwgLayerTableChanges Method
  • Editor.PostCommandPrompt Method
• Autodesk.AutoCAD.GraphicsInterface
  • TextStyle.FromTextStyleTableRecord Method
  • TextStyle.ToTextStyleTableRecord Method
• Autodesk.AutoCAD.Windows
  • Window.Focus Method
• Autodesk.AutoCAD.ApplicationServices.Core
  • Application.LoadJSScript Method

The Developer's Guide was updated in the following areas were changed:

• Viewports and layouts
• Plotting and publishing
• Document events
• Disposal of objects
• Plot styles
• Visual styles and render presets
• Raster images and xrefs
• Clipping blocks, xrefs, and raster images
• Defining and inserting blocks, and working with attributes

The .NET Developer's Guide is part of the product help.

Hope this helps give you an understanding of the changes that you might or might not need to make with your custom programs.

Sincerely,
  Lee

AutoCAD Developer Documentation Survey

Do you create AutoLISP, VBA, .NET, or ObjectARX applications to automate tasks for your company or to solve problems for a client?  If so, chances are you might have used the AutoCAD developer documentation. The Learning Experience team would like some input on the developer documentation via the AutoCAD Developer Documentation Survey. The survey will take 5-10 minutes of your time.

Here is the link to the survey -
https://www.surveymonkey.com/s/H72RWJC

Sincerely,
  Lee

Updated AutoCAD 2013 ActiveX Developer Documentation

A new update to the AutoCAD 2013 ActiveX Developer Documentation has recently been made available through the AutoCAD Developer Center. The updated documentation set can be found at the bottom of the page under the Documentation section.

The updates that were made to the documentation are:

• Corrections to the existing VBA samples
• VBA samples ported to show the use of AutoLISP/Visual LISP
• Reference documentation updated to include all the latest and previously missing classes/properties/methods
• Full list of changes to the API from AutoCAD 2000 through AutoCAD 2013
• Corrections to and the inclusion of the ActiveX Developer's Guide

To utilize the documentation with the VBA IDE or Visual LISP IDE, download and extract the contents of the ZIP file to the following location:

C:\Program Files\Common Files\Autodesk Shared

Sincerely,
  Lee

Hooking Up Custom Help for Your Commands

Help is commonly one of the last things that many new developers think about or never think about, but it should be one of the first things you work on as it is your first line of support for your custom utilities.  AutoCAD provides ways for you to call a help topic or file, and hook up F1 support for your custom commands that you define with AutoLISP, .NET, or ObjectARX.

In this article, I focus on calling help and hooking up F1 support for commands defined using AutoLISP.  To accomplish these tasks, you use the HELP and SETFUNHELP functions.

Both the HELP and SETFUNHELP functions support the use of HyperText Markup Language (HTM/HTML), Microsoft Help (CHM), and WinHelp (HLP) files.  When you make a call to a HTM/HTML file, the file is loaded into the AutoCAD Help browser.  CHM and HLP files are displayed in their respective application windows.

The syntax for the HELP function is:

(help [help_file [chm_hlp_topic [chm_help_window_command]]])

The following examples demonstrate how to directly call help from AutoCAD:

;; Displays the topic for the LINE command from the default AutoCAD help
(help "" "LINE")

;; Displays a Web page
(help "http://www.hyperpics.com/")

;; Displays a local HTML file
(help "C:\\Program Files\\Autodesk\\AutoCAD 2013 Help\\English\\Help\\index.html")

;; Displays a CHM file
(help "acet.chm" "html/BLOCKREPLACE")

Now that you have seen how to call help with the HELP function, the SETFUNHELP function is very similar with the exception of needing to provide the name of the function.  The function name must include the 'c:' (command) prefix.

The syntax for the SETFUNHELP function is:

(setfunhelp c:function_name [help_file [chm_hlp_topic [chm_help_window_command]]])

The following examples demonstrate how to set up contextual/F1 help for custom commands:

;; Displays the topic for the LINE command from the default AutoCAD help
(defun c:CMD1 () (getstring "\nEnter some text: "))
(setfunhelp "c:CMD1" "" "LINE")

;; Displays a Web page
(defun c:CMD2 () (getstring "\nEnter some text: "))
(setfunhelp "c:CMD2" "http://www.hyperpics.com/")

;; Displays a local HTML file
(defun c:CMD3 () (getstring "\nEnter some text: "))
(setfunhelp "c:CMD3" "C:\\Program Files\\Autodesk\\AutoCAD 2013 Help\\English\\Help\\index.html")

;; Displays a CHM file
(defun c:CMD4 () (getstring "\nEnter some text: "))
(setfunhelp "c:CMD4" "acet.chm" "html/BLOCKREPLACE")

Once the command is defined and the Help topic is associated with the command, you can display the topic by pressing F1 under the following situations:

• When AutoComplete is enabled and the full name of the command is displayed, but the command is not started yet.
• When the command is active.

For more information on these two functions, see the following:

• help (AutoLISP)
• setfunhelp (AutoLISP)

Sincerely,
  Lee

Create a Table and Select a Cell to Change with AutoLISP and ActiveX

Tables are one of the most complex objects, after dimensions, to create and edit through the APIs that AutoCAD offers.  The appearance of a table is controlled by its properties and methods, along with the table style that it is assigned.  Tables are made up of individual cells which can contain text, blocks, and formulas along with additional formatting.

In the previous posting, Creating a Table Style with AutoLISP and the ActiveX API, I showed an exmple of how to create a custom table style.

In this article, I show for to create a table and then edit the value of a cell by picking a point within a table cell.

(vl-load-com)

;; Example adds a table to model space that is 5 rows by 3 columns
;; with a row height of 10 units and column width of 30 units
(defun c:AddTable( / acadObj curDoc insPt mSpaceObj tableObj)
    (setq acadObj (vlax-get-acad-object))
    (setq curDoc (vla-get-ActiveDocument acadObj))

    (setq insPt (vlax-3d-point 0 0 0))

    (setq mSpaceObj (vla-get-ModelSpace curDoc))
    (setq tableObj (vla-Addtable mSpaceObj insPt 5 3 10 30))

    (vla-put-StyleName tableObj "MyTableStyle")
)

;; Example shows how to pick a single table cell on screen and change its value.
;; This example demonstrates the ActiveX properties/methods HitTest,
;; GetCellType, GetText and SetText.
(defun c:SelectTableCell ( / pick vHeight vWidth lwrLeft uprRight vector
                                           SS_TABLES cnt eMax tableObj row col cellValueOrg)
 
  ;; Ask the user for a point on screen
  (if (/= (setq pick (vlax-3d-point (getpoint "\nSelect Cell to edit: "))) nil)
    (progn

      ;; Get the corners of the screen display to build our selection set
      (setq vHeight (getvar "viewsize"))
      (setq vWidth (* (/ (nth 0 (getvar "screensize")) (nth 1 (getvar "screensize"))) vHeight))

      (setq lwrLeft (list (- (nth 0 (getvar "viewctr")) (/ vWidth 2)) (- (nth 1 (getvar "viewctr")) (/ vHeight  2)) 0))
      (setq uprRight (list (+ (nth 0 (getvar "viewctr")) (/ vWidth 2)) (+ (nth 1 (getvar "viewctr")) (/ vHeight  2)) 0))

      ;; Get the current display orientation
      (setq vector (vlax-make-safearray vlax-vbDouble '(0 . 2)))
      (vlax-safearray-fill vector '(1 1 1))
      (setq vector (vlax-make-variant vector))
     
      ;; Select all the table objects visible on screen
      (if (setq SS_TABLES (ssget "C" lwrleft uprright (list (cons 0 "ACAD_TABLE"))))
        (progn
  
          (setq cnt 0
                eMax (sslength SS_TABLES)
          )

          ;; Step through all the items in the selection set
          (while (> eMax cnt)
            ;; Geta table object from the selection set
            (setq tableObj (vlax-ename->vla-object (ssname SS_TABLES cnt)))
 
            ;; Return values for what cell was picked in
            (setq row 0
                  col 0)

            ;; Below is also a sample to see if a valid cell is picked
            ;; (vla-select table pick vector vector 5 5 :vlax-false 'row 'col)
    
            ;; Check to see if a valid cell was picked
            (if (= (vla-hittest tableObj pick vector 'row 'col) :vlax-true)
              (progn

                ;; Get out of the loop
                (setq cnt (1+ eMax))
  
                ;; Check to see what the Cell Type is (Text or Block)
                (if (= (vla-GetCellType tableObj row col) acTextCell)
                  (progn
                    ;; Let's get the value out
                    (setq cellValueOrg (vla-GetText tableObj row col))

                    ;; Change the current value
                    (vla-SetText tableObj row col "Revised Text")
                    (vla-Update tableObj)
                    (alert "Cell text was changed.")
         
                    ;; Restore the original value
                    (vla-SetText tableObj row col cellValueOrg)
                    (vla-Update tableObj)
                    (alert "Cell text was changed back to the original value.")
                    (setq cnt eMax)
                  )
                )
              )
            )
            (setq cnt (1+ cnt))
          )
        )
      )
    )
  )
 (princ)
)

Sincerely,
  Lee

Creating a Table Style with AutoLISP and the ActiveX API

Table styles in AutoCAD are primarily created using the Table Style dialog box (TABLESTYLE command) since there is no command line support, which limits the ability of creating a table style using a script or the COMMAND function in AutoLISP.  However, you can leverage the ActiveX API to create or modify table style and cell styles defined in your current drawing.

NOTE: ActiveX API is not available on AutoCAD for Mac.

To create a table style, you must access the ACAD_TABLESTYLE dictionary in the current drawing.  Once a reference to the ACAD_TABLESTYLE dictionary is obtained, you can then check to see if a table style already exists using the VLA-GETOBJECT function or add a table style using the VLA-ADDOBJECT function.

The following sample code demonstrates how to create a new table style, but does not check to see if the table style already exists first.  If the table style does exist, an error will occur.

(vl-load-com)
(defun c:CreateTableStyle()
    ;; Get the AutoCAD application and current document
    (setq acad (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acad))

    ;; Get the Dictionaries collection and the TableStyle dictionary
    (setq dicts (vla-get-Dictionaries doc))
    (setq dictObj (vla-Item dicts "acad_tablestyle"))
   
    ;; Create a custom table style
    (setq key "MyTableStyle"
          class "AcDbTableStyle")
    (setq custObj (vla-AddObject dictObj key class))

    ;; Set the name and description for the style
    (vla-put-Name custObj "MyTableStyle")
    (vla-put-Description custObj "This is my custom table style")

    ;; Sets the bit flag value for the style
    (vla-put-BitFlags custObj 1)

    ;; Sets the direction of the table, top to bottom or bottom to top
    (vla-put-FlowDirection custObj acTableTopToBottom)

    ;; Sets the supression of the table header
    (vla-put-HeaderSuppressed custObj :vlax-false)

    ;; Sets the horizontal margin for the table cells
    (vla-put-HorzCellMargin custObj 0.22)

    ;; Sets the supression of the table title
    (vla-put-TitleSuppressed custObj :vlax-false)

    ;; Sets the vertical margin for the table cells
    (vla-put-VertCellMargin custObj 0.22)

    ;; Set the alignment for the Data, Header, and Title rows
    (vla-SetAlignment custObj (+ acDataRow acTitleRow) acMiddleLeft)
    (vla-SetAlignment custObj acHeaderRow acMiddleCenter)

    ;; Set the background color for the Header and Title rows
    (setq colObj (vlax-create-object "AutoCAD.AcCmColor.19"))
    (vla-SetRGB colObj 98 136 213)
    (vla-SetBackgroundColor custObj (+ acHeaderRow acTitleRow) colObj)

    ;; Clear the background color for the Data rows
    (vla-SetBackgroundColorNone custObj acDataRow :vlax-true)

    ;; Set the bottom grid color for the Title row
    (vla-SetRGB colObj 0 0 255)
    (vla-SetGridColor custObj acHorzBottom acTitleRow colObj)

    ;; Set the bottom grid lineweight for the Title row
    (vla-SetGridLineWeight tableStyle acHorzBottom acTitleRow acLnWt025)

    ;; Set the inside grid lines visible for the data and header rows
    (vla-SetGridVisibility custObj acHorzInside  (+ acDataRow acHeaderRow) :vlax-true)

    ;; Set the text height for the Title, Header and Data rows
    (vla-SetTextHeight custObj acTitleRow 1.5)
    (vla-SetTextHeight custObj (+ acDataRow acHeaderRow) 1.0)

    ;; Set the text height and style for the Title row
    (vla-SetTextStyle custObj (+ acDataRow acHeaderRow acTitleRow) "Standard")

    ;; Release the color object
    (vlax-release-object colObj)
  (princ)
)

The following image shows what the table style looks like when applied to a table object.

Sincerely,
  Lee

 

Listing Defined AutoLISP Variables and Functions

AutoLISP is one of the oldest and easiest ways of extending AutoCAD, but did you ever wonder what functions are currently defined or which global variables are already set?

The ATOMS-FAMILY (not the Adams Family) function returns a list of all the symbols, global variables, and functions currently defined for use by AutoLISP.  You can also use the function to check to see if a specific symbol, global variable, and/or function is currently defined or set.  This ability to check for the existence of previous definitions is helpful if you want to see which functions are exposed before loading an AutoLISP file.

Syntax:

(atoms-family format [symbol_list])

format - Determines how the values in the returned list are formated. Valid values are 0 for Symbols or 1 for Strings.

symbol_list - Optional; List of symbols, variables, or functions to search for.

For example:

Entering (atoms-family 1) at the Command prompt returns a long list that might look like the following.

("ACTOOLBARDOCKBOTTOM" "ACET-VAR-SETVAR" "ACVIEWPORT4" "AC3IN_1FT" "VLA-ADDBOX"
...
"VLA-GET-SHOWPLOTSTYLES" "VLA-GET-NUMCELLSTYLES" "AI_RETURN" "C:SAVEALL")

The list returned is useful, but can take a while to sort through as it is not in alphabetical order or an order that will make much sense.

As mentioned previously, you can use the ATOMS-FAMILY function to test for the existence of a symbol, function, or variable by passing in a list of the items you want to see exist.  This check can be helpful if your routines depend on the definition of a function from a previously loaded file.  If the check fails, you can then load the necessary file.

For example:

Entering (atoms-family 1 '("getpoint" "getpoints" "PI")) at the Command prompt returns a long list that might look like the following.

("GETPOINT" nil "PI")

The following is some sample code that exports the symbols, functions, global variables, and commands that are defined via AutoLISP or exposted to AutoLISP from .NET/ObjectARX.  The command that is defined creates four lists, and then sorts each before exporting the definitions out.  To determine the type of definition in the list returned by ATOMS-FAMILY, I used the TYPE function and to see if a definition is prefixed with "C:" to determine which functions at like a command at the Command prompt.

After the command is ran, the number of symbols, functions, global variables, and commands is output to the Command Line window, and a file named LspDumpFile.log is created under the root of the C drive.  You can do a comparison AutoLISP definitions by exporting out what is currently defined, renamed the file created, load an AutoLISP file, and then before a second export.  To do the comparison between the files, you can use a utility like WinDiff or UltraEdit or even MS Word.

(defun c:LISPDumpFile ( / afList nSyms nFuncs nCmds nVars
                                        lstSyms lstFuncs lstCmds lstVars
                                        item fp)
    (setq afList (atoms-family 1))
    (setq nSyms 0 nFuncs 0 nCmds 0 nVars 0
             lstSyms nil lstFuncs nil lstCmds nil lstVars nil)
    (foreach item aflist
        (progn
           (cond
               ((= (type (eval (read item))) 'SYM)
                    (progn
                        (setq nSyms (1+ nSyms))
                        (if (/= lstSyms nil)
                            (setq lstSyms (append lstSyms (list item)))
                            (setq lstSyms (list item))
                        )
                    )
               )
               ((and (= (type (eval (read item))) 'SUBR) (/= (substr (strcase item) 1 2) "C:"))
                     (progn
                          (setq nFuncs (1+ nFuncs))
                          (if (/= lstFuncs nil)
                              (setq lstFuncs (append lstFuncs (list item)))
                              (setq lstFuncs (list item))
                          )                
                     )
               )
               ((and (= (type (eval (read item))) 'SUBR) (= (substr (strcase item) 1 2) "C:"))
                     (progn
                          (if (/= (strcase item) (strcase "c:LISPDumpFile"))
                              (progn
                                  (setq nCmds (1+ nCmds))
                                  (if (/= lstCmds nil)
                                      (setq lstCmds (append lstCmds (list item)))
                                      (setq lstCmds (list item))
                                  )
                              )
                          )
                     )
               )
               ((or (= (type (eval (read item))) 'REAL)
                    (= (type (eval (read item))) 'INT)
                    (= (type (eval (read item))) 'LIST)
                    (= (type (eval (read item))) 'PICKSET)
                    (= (type (eval (read item))) 'ENAME)
                    (= (type (eval (read item))) 'VLA-OBJECT)
                    (= (type (eval (read item))) 'FILE)
                    (= (type (eval (read item))) 'VARIANT)
                    (= (type (eval (read item))) 'STR))
                        (progn
                            (setq nVars (1+ nVars))
                            (if (/= lstVars nil)
                                (setq lstVars (append lstVars (list item)))
                                (setq lstVars (list item))
                            )
                        )
               )
           )
        )
    )
    ;; Output details about defined Symbols and Functions
    (prompt (strcat "\nAutoLISP Symbols and Functions count: "
                    "\nSymbols - " (itoa nSyms)
                    "\nFunctions - " (itoa nFuncs)
                    "\nGlobal Variables - " (itoa nVars)
                    "\nCommands - " (itoa nCmds))
    )
    (setq fp (open "c:\\LspDumpFile.log" "w"))
    (write-line "Symbols" fp)
    (setq lstSyms (acad_strlsort lstSyms))
    (foreach item lstSyms
        (write-line item fp)
    )
    (write-line "" fp)
    (write-line "Functions" fp)
    (setq lstFuncs (acad_strlsort lstFuncs))
    (foreach item lstFuncs
        (write-line item fp)
    )
    (write-line "" fp)
    (write-line "Global Variables" fp)
    (setq lstVars (acad_strlsort lstVars))
    (foreach item lstVars
        (write-line item fp)
    )
    (write-line "" fp)
    (write-line "Commands" fp)
    (setq lstCmds (acad_strlsort lstCmds))
    (foreach item lstCmds
        (write-line item fp)
    )
    (close fp)
  (princ)
)

The following is a sampling of the LOG file that is generated.

Symbols
*LAST-VALUE*
:AUTOLISP
...

Functions
-
*
*ERROR*
*MERR*
...

Global Variables
AC0DEGREES
AC1_1
AC1_10
...

Commands
C:-BLOCKREPLACE
C:-BLOCKTOXREF
C:-CDORDER
...

Sincerely,
  Lee

External Link of Interest:
Commands that “work” in the AutoCAD 2013 Core Console - Through the Interface (by Kean Walmsley)

 

AutoLISP API Changes for AutoCAD 2013 - Updated

AutoLISP has been in AutoCAD for a long time, well before my time when I started with AutoCAD R12 for DOS in 1994.  At its core, AutoLISP really has not changed much in the past 15 years outside of the introduction of Visual LISP and the ability to utilize the ActiveX API on Windows.

There were a few additions to the Visual LISP extension in AutoCAD 2013 which expose some new functionality from the ActiveX API and a few new functions that allow you to obtain the Machine and User product keys of AutoCAD.  Along with some new functions, there are some new variables introduced as a result of new constants being added to the ActiveX API.

To use the the changes made to the Visual LISP extension, be sure to call the VL-LOAD-COM function first.

New Functions:
VLA-GET-ACTIVEINVPROJECT / VLA-PUT-ACTIVEINVPROJECT - Specifies the active Inventor project being used by the Model Documentation feature. (Internal Use Only)
VLA-GET-INTENSITYCOLORSCHEME / VLA-PUT-INTENSITYCOLORSCHEME - Specifies the color scheme to use for displaying intensity values.
VLA-GET-SHOWCLIPPED / VLA-PUT-SHOWCLIPPED - Enables or disables the clipping boundary.
VLA-GET-SHOWINTENSITY / VLA-PUT-SHOWINTENSITY - Specifies if the point cloud is displayed using a shaded color scheme.
VLA-PUT-LENGTH - Sets the Length property for a point cloud.
VLAX-MACHINE-PRODUCT-KEY - Returns the AutoCAD product key from the Machine hive in the Windows Registry.  (ie. "Software\\Autodesk\\AutoCAD\\R19.0\\ACAD-B001:409")
VLAX-USER-PRODUCT-KEY - Returns the AutoCAD product keyfrom the User hive in the Windows Registry.  (ie. "Software\\Autodesk\\AutoCAD\\R19.0\\ACAD-B001:409")

Obsolete Functions:
VLAX-PRODUCT-KEY - While still supported, it is recommended to use the new function VLAX-MACHINE-PRODUCT-KEY instead which returns the same value.

Changed Variables:
ACNATIVE = 60

New Variables:
AC2013_DWG = 60
AC2013_DXF = 61
AC2013_TEMPLATE = 62
ACINTENSITYBLUE = 4
ACINTENSITYEDITABLEFLAG = 5
ACINTENSITYGRAYSCALE = 0
ACINTENSITYGREEN = 3
ACINTENSITYRAINBOW = 1
ACINTENSITYRED = 2
ACTRUECOLOR = 0

See Also:
ActiveX API Changes in AutoCAD 2013

***Updated 7/10/12 to include the change to VLAX-PRODUCT-KEY.

Sincerely,
  Lee

ActiveX API Changes in AutoCAD 2013

While the ActiveX API typically does not see significant changes between releases like the Managed .NET and ObjectARX APIs do, it is still useful to know what changes were made.  There were really no major changes made to the AutoCAD 2013 ActiveX API, outside of the following three areas:

• Drawing file format (AcSaveAsType Enum)
• PointCloud property and enum additions
• Checking the interference of a 3DSolid (CheckInterference method)

Note: The AutoCAD ActiveX API can be used with AutoLISP, VBA, .NET, and C++ but only on Windows and not on Mac OS.

A full list of the changes made to the AutoCAD 2013 ActiveX API are:

Changed Enums:
AcSaveAsType
        ac2013_dwg = 60 (New)
        ac2013_dxf = 61 (New)
        ac2013_Template = 62 (New)
        acNative = 60 (Changed)

New Enums:
AcPointCloudIntensityStyle
        acIntensityGrayscale = 0
        acIntensityRainbow = 1
        acIntensityRed = 2
        acIntensityGreen = 3
        acIntensityBlue = 4
        acIntensityEditableFlag = 5
AcPointCloudColorType
        acTrueColor = 0
        acByColor = 1

Changed Classes:
IAcad3DSolid
        CheckInterference - Method (Added solid interfere parameter)
IAcadDynamicBlockReferenceProperty (Changed)
        show - Property (Renamed, previously Show)
IAcadEntity
        EntityTransparency - Property (New)
IAcadHatch
        BackgroundColor - Property (New)
IAcadLoftedSurface
        EndSmoothContinuity - Property (New)
        EndSmoothMagnitude - Property (New)
        Periodic - Property
        StartSmoothContinuity - Property (New)
        StartSmoothMagnitude - Property (New)
IAcadPointCloud
        Height - Property (New)
        IntensityColorScheme - Property (New)
        Length - Property (New)
        Name - Property (New)
        Path - Property (New)
        ShowClipped - Property (New)
        ShowIntensity - Property (New)
        Width - Property (New)
IAcadPreferencesFiles
        ActiveInvProject - Property (New)
IAcadRasterImage
        transparency - Property (Renamed, previously Transparency)
IAcadSpline
        Closed2 - Property (New)
        Degree2 - Property (New)
        KnotParameterization - Property (New)
        SplineFrame - Property (New)
        SplineMethod - Property (New)
IAcadSurface
        EdgeExtensionDistances - Property (New)
        MaintainAssociativity - Property (New)
        ShowAssociativity - Property (New)
        SurfTrimAssociativity - Property (New)
        WireframeType - Property (New)

Removed Classes:
Classes were merged with the class in which they were derived in most cases (ie. IAcadEntity2 -> IAcadEntity)
IAcad3DFace2
IAcad3DPolyline2
IAcad3DSolid2
IAcadArc2
IAcadAttribute2
IAcadBlockReference2
IAcadCircle2
IAcadDim3PointAngular2
IAcadDimAligned2
IAcadDimAngular2
IAcadDimArcLength2
IAcadDimDiametric2
IAcadDimOrdinate2
IAcadDimRadial2
IAcadDimRadialLarge2
IAcadDimRotated2
IAcadEllipse2
IAcadEntity2
IAcadExternalReference2
IAcadExtrudedSurface2
IAcadExtrudedSurface3
IAcadHatch2
IAcadHelix2
IAcadLine2
IAcadLeader2
IAcadLoftedSurface2
IAcadLoftedSurface3
IAcadLWPolyline2
IAcadMLeader2
IAcadMText2
IAcadNurbSurface2
IAcadOle2
IAcadPlaneSurface2
IAcadPlaneSurface3
IAcadPoint2
IAcadPolyfaceMesh2
IAcadPolygonMesh2
IAcadPolyline2
IAcadPViewport2
IAcadRay2
IAcadRasterImage2
IAcadRegion2
IAcadRevolvedSurface2
IAcadRevolvedSurface3
IAcadShape2
IAcadSolid2
IAcadSpline2
IAcadSurface2
IAcadSurface3
IAcadSweptSurface2
IAcadSweptSurface3
IAcadSubDMesh2
IAcadTable2
IAcadText2
IAcadTolerance2
IAcadTrace2
IAcadXline2
IAcadWipeout2

Sincerely,
  Lee

Plotting and Creating Page Setups with AutoLISP

Plotting is a key step in communicating your design with non-AutoCAD users unless you are using AutoCAD WS or another way of hosting your designs for others to see.  While many users go straight to the PLOT command and never bother with page setups, page setups can make plotting a drawing much more consistent and easier if you need to plot your designs at different sizes or formats.  One reason to plot the same layout or design at different sizes might be for a check plot and the other to a specific scale.

Note: This article does not work for those using AutoCAD for Mac because it does not support ActiveX.

The following demonstrates how to plot a layout using a PC3 file.  It first checks to see if a PC3 file is assigned to the current layout for plotting, and if not it assigns the DWF6 ePlot.pc3 file as the current plot device.  Using this same approach, you could plot all layouts in a drawing to PDF or DWF files without changing the current plot configuration, much like the way the PUBLISH command works.

(vl-load-com)
(defun c:QDWF( / doc)
    ;; Get the current drawing
    (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))

    ;; Plot the current layout
    (vla-PlotToDevice (vla-get-Plot doc) "DWF6 ePlot.pc3")
  (princ)
)

The vla-PlotToDevice function above is passed a valid PC3 file, but if you do not pass a PC3 file to the method it will use the plot device assigned to the layout which can be accessed with the vla-get-ConfigName function.

Note: The vla-PlotToDevice function will start plotting in the background or foreground based on the current value of the BACKGROUNDPLOT system variable.

Now that you see how to plot a single layout, you can plot multiple layouts using the vla-SetLayoutsToPlot function.

(defun c:PLOTALL( / doc)
    ;; Get the current drawing
    (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))

    (setq lstLayouts nil
          arSize 0)

    (vlax-for layout (vla-get-layouts doc)
        ;; Check to see if a plot device is assigned to the layout, if not it will not be plotted
        (if (and
                (/= (strcase (vla-get-ConfigName layout)) "NONE")
                (= (vla-get-ModelType layout) :vlax-false)
            )
            (progn
                (if (= lstLayouts nil)
                    (setq lstLayouts (list (vla-get-Name layout)))
                    (setq lstLayouts (append lstLayouts (vla-get-Name layout)))
                )
            )
        )
    )

    ;; Create an array for all the layouts to be plotted
    (setq arLayouts (vlax-make-safearray vlax-vbString (cons 0 (1- (length lstLayouts)))))

    ;; Add the layout names to the array
    (foreach item lstLayouts
        (progn
            (vlax-safearray-put-element arLayouts arSize item)
            (setq arSize (1+ arSize))
        )
    )

    ;; Plot the layout to the device
    (vla-SetLayoutsToPlot (vla-get-Plot doc) arLayouts)
    (vla-PlotToDevice (vla-get-Plot doc))

  (princ)
)

The following demonstrates how to create a named page setup, and then assign it to the current layout.

(defun c:CustomPageSetup()
    ;; Get the current drawing
    (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))

    ;; Get the PlotConfigurations collection
    (setq plotCfgs (vla-get-PlotConfigurations doc))

    ;; Check to see if the pagesetup already exists
    (setq plotCfg (vl-catch-all-apply 'vla-Item (list plotCfgs "MYPAGESETUP")))

    ;; If the page setup exists, the variable will be of type VLA-OBJECT
    (if (/= (type plotCfg) 'VLA-OBJECT)
        ;; Create a page setup for model or paper space accordingly
        (if (= (getvar "TILEMODE") 0) 
            (setq plotCfg (vla-Add plotCfgs "MYPAGESETUP" :vlax-false))
            (setq plotCfg (vla-Add plotCfgs "MYPAGESETUP" :vlax-true))
        )
    )

    ;;(vla-put-Name plotCfg "MYPAGESETUP")
    (vla-RefreshPlotDeviceInfo plotCfg)
 
    ;; Set the plot device
    (vla-put-ConfigName plotCfg "DWF6 ePlot.pc3")

    ;; Set the paper size
    (vla-put-CanonicalMediaName plotCfg "ANSI_C_(22.00_x_17.00_Inches)")

    ;; Set the plot units (inches, millimeters, pixels)
    (vla-put-PaperUnits plotCfg acInches)

    ;; Set what to plot
    ;; - If using acView, set the ViewToPlot property
    ;; - If using acWindow, call GetWindowToPlot
    (if (= (getvar "TILEMODE") 0)
        (progn
            (vla-put-PlotType plotCfg acLayout)

            ;; Set scale
            (vla-put-UseStandardScale plotCfg :vlax-true)
            (vla-put-StandardScale plotCfg ac1_1)         
        )
        (progn
            (vla-put-PlotType plotCfg acExtents)

            ;; Set scale
            (vla-put-UseStandardScale plotCfg :vlax-true)
            (vla-put-StandardScale plotCfg acScaleToFit)
         
            ;; Center the plot on the page
            (vla-put-CenterPlot plotCfg :vlax-true)
        )
    )

    ;; Hide paperspace objects
    (vla-put-PlotHidden plotCfg :vlax-false)

    ;; Set the plot origin
    (setq origin (vlax-make-safearray vlax-vbDouble '(0 . 1)))
    (vlax-safearray-fill origin (list 0.5 0.5))
    (vla-put-PlotOrigin plotCfg origin)

    ;; Set the plot rotation
    (vla-put-PlotRotation plotCfg ac0degrees)

    ;; Set viewport plot behavior
    (vla-put-PlotViewportBorders plotCfg :vlax-false)
    (vla-put-PlotViewportsFirst plotCfg :vlax-true)

    ;; Set lineweight behavior
    (vla-put-PlotWithLineweights plotCfg :vlax-true)
    (vla-put-ScaleLineweights plotCfg :vlax-true)

    ;; Set plot styles behavior
    (vla-put-PlotWithPlotStyles plotCfg :vlax-true)
    (vla-put-ShowPlotStyles plotCfg :vlax-true)

    (if (= (getvar "PSTYLEMODE") 0)
        (vla-put-StyleSheet plotCfg "acad.stb")
        (vla-put-StyleSheet plotCfg "acad.ctb")
    )

    ;; Assign the page setup to the current layout
    (vla-CopyFrom (vla-get-ActiveLayout doc) plotCfg)
)

Hope you enjoyed the sample code.

Sincerely,
  Lee