HyperPics: Beyond the UI

Creating a Table Style with AutoLISP and the ActiveX API

Table styles in AutoCAD are primarily created using the Table Style dialog box (TABLESTYLE command) since there is no command line support, which limits the ability of creating a table style using a script or the COMMAND function in AutoLISP.  However, you can leverage the ActiveX API to create or modify table style and cell styles defined in your current drawing.

NOTE: ActiveX API is not available on AutoCAD for Mac.

To create a table style, you must access the ACAD_TABLESTYLE dictionary in the current drawing.  Once a reference to the ACAD_TABLESTYLE dictionary is obtained, you can then check to see if a table style already exists using the VLA-GETOBJECT function or add a table style using the VLA-ADDOBJECT function.

The following sample code demonstrates how to create a new table style, but does not check to see if the table style already exists first.  If the table style does exist, an error will occur.

(vl-load-com)
(defun c:CreateTableStyle()
    ;; Get the AutoCAD application and current document
    (setq acad (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acad))

    ;; Get the Dictionaries collection and the TableStyle dictionary
    (setq dicts (vla-get-Dictionaries doc))
    (setq dictObj (vla-Item dicts "acad_tablestyle"))
   
    ;; Create a custom table style
    (setq key "MyTableStyle"
          class "AcDbTableStyle")
    (setq custObj (vla-AddObject dictObj key class))

    ;; Set the name and description for the style
    (vla-put-Name custObj "MyTableStyle")
    (vla-put-Description custObj "This is my custom table style")

    ;; Sets the bit flag value for the style
    (vla-put-BitFlags custObj 1)

    ;; Sets the direction of the table, top to bottom or bottom to top
    (vla-put-FlowDirection custObj acTableTopToBottom)

    ;; Sets the supression of the table header
    (vla-put-HeaderSuppressed custObj :vlax-false)

    ;; Sets the horizontal margin for the table cells
    (vla-put-HorzCellMargin custObj 0.22)

    ;; Sets the supression of the table title
    (vla-put-TitleSuppressed custObj :vlax-false)

    ;; Sets the vertical margin for the table cells
    (vla-put-VertCellMargin custObj 0.22)

    ;; Set the alignment for the Data, Header, and Title rows
    (vla-SetAlignment custObj (+ acDataRow acTitleRow) acMiddleLeft)
    (vla-SetAlignment custObj acHeaderRow acMiddleCenter)

    ;; Set the background color for the Header and Title rows
    (setq colObj (vlax-create-object (strcat "AutoCAD.AcCmColor." (substr (getvar "ACADVER") 1 2))))
    (vla-SetRGB colObj 98 136 213)
    (vla-SetBackgroundColor custObj (+ acHeaderRow acTitleRow) colObj)

    ;; Clear the background color for the Data rows
    (vla-SetBackgroundColorNone custObj acDataRow :vlax-true)

    ;; Set the bottom grid color for the Title row
    (vla-SetRGB colObj 0 0 255)
    (vla-SetGridColor custObj acHorzBottom acTitleRow colObj)

    ;; Set the bottom grid lineweight for the Title row
    (vla-SetGridLineWeight custObj acHorzBottom acTitleRow acLnWt025)

    ;; Set the inside grid lines visible for the data and header rows
    (vla-SetGridVisibility custObj acHorzInside  (+ acDataRow acHeaderRow) :vlax-true)

    ;; Set the text height for the Title, Header and Data rows
    (vla-SetTextHeight custObj acTitleRow 1.5)
    (vla-SetTextHeight custObj (+ acDataRow acHeaderRow) 1.0)

    ;; Set the text height and style for the Title row
    (vla-SetTextStyle custObj (+ acDataRow acHeaderRow acTitleRow) "Standard")

    ;; Release the color object
    (vlax-release-object colObj)
  (princ)
)

The following image shows what the table style looks like when applied to a table object.

Sincerely,
  Lee

 

Preview Guides for AutoCAD 2004 through 2013

Looking for what has changed in the latest release or maybe over the course of several releases of AutoCAD?  Maybe you have not used AutoCAD for a while, or maybe you are using AutoCAD but are in the process of upgrading from a older release.  Whatever your current situation, hopefully the following Preview Guides will be helpful to you:

AutoCAD 2013 Preview Guide
AutoCAD 2012 Preview Guide
AutoCAD 2011 Preview Guide
AutoCAD 2010 Preview Guide
AutoCAD 2009 Preview Guide
AutoCAD 2008 Preview Guide
AutoCAD 2007 Preview Guide
AutoCAD 2006 Preview Guide
AutoCAD 2005 Preview Guide
AutoCAD 2004 Preview Guide

The Preview guides can be found posted on the AutoCAD Insider blog which is authored by Heidi Hewett, and recently with Kate Morrical as well.  Kate also authors her own blog called LT Unlimited for AutoCAD LT users.

Sincerely,
  Lee

AutoLISP API Changes for AutoCAD 2013 - Updated

AutoLISP has been in AutoCAD for a long time, well before my time when I started with AutoCAD R12 for DOS in 1994.  At its core, AutoLISP really has not changed much in the past 15 years outside of the introduction of Visual LISP and the ability to utilize the ActiveX API on Windows.

There were a few additions to the Visual LISP extension in AutoCAD 2013 which expose some new functionality from the ActiveX API and a few new functions that allow you to obtain the Machine and User product keys of AutoCAD.  Along with some new functions, there are some new variables introduced as a result of new constants being added to the ActiveX API.

To use the the changes made to the Visual LISP extension, be sure to call the VL-LOAD-COM function first.

New Functions:
VLA-GET-ACTIVEINVPROJECT / VLA-PUT-ACTIVEINVPROJECT - Specifies the active Inventor project being used by the Model Documentation feature. (Internal Use Only)
VLA-GET-INTENSITYCOLORSCHEME / VLA-PUT-INTENSITYCOLORSCHEME - Specifies the color scheme to use for displaying intensity values.
VLA-GET-SHOWCLIPPED / VLA-PUT-SHOWCLIPPED - Enables or disables the clipping boundary.
VLA-GET-SHOWINTENSITY / VLA-PUT-SHOWINTENSITY - Specifies if the point cloud is displayed using a shaded color scheme.
VLA-PUT-LENGTH - Sets the Length property for a point cloud.
VLAX-MACHINE-PRODUCT-KEY - Returns the AutoCAD product key from the Machine hive in the Windows Registry.  (ie. "Software\\Autodesk\\AutoCAD\\R19.0\\ACAD-B001:409")
VLAX-USER-PRODUCT-KEY - Returns the AutoCAD product keyfrom the User hive in the Windows Registry.  (ie. "Software\\Autodesk\\AutoCAD\\R19.0\\ACAD-B001:409")

Obsolete Functions:
VLAX-PRODUCT-KEY - While still supported, it is recommended to use the new function VLAX-MACHINE-PRODUCT-KEY instead which returns the same value.

Changed Variables:
ACNATIVE = 60

New Variables:
AC2013_DWG = 60
AC2013_DXF = 61
AC2013_TEMPLATE = 62
ACINTENSITYBLUE = 4
ACINTENSITYEDITABLEFLAG = 5
ACINTENSITYGRAYSCALE = 0
ACINTENSITYGREEN = 3
ACINTENSITYRAINBOW = 1
ACINTENSITYRED = 2
ACTRUECOLOR = 0

See Also:
ActiveX API Changes in AutoCAD 2013

***Updated 7/10/12 to include the change to VLAX-PRODUCT-KEY.

Sincerely,
  Lee

ActiveX API Changes in AutoCAD 2013

While the ActiveX API typically does not see significant changes between releases like the Managed .NET and ObjectARX APIs do, it is still useful to know what changes were made.  There were really no major changes made to the AutoCAD 2013 ActiveX API, outside of the following three areas:

• Drawing file format (AcSaveAsType Enum)
• PointCloud property and enum additions
• Checking the interference of a 3DSolid (CheckInterference method)

Note: The AutoCAD ActiveX API can be used with AutoLISP, VBA, .NET, and C++ but only on Windows and not on Mac OS.

A full list of the changes made to the AutoCAD 2013 ActiveX API are:

Changed Enums:
AcSaveAsType
        ac2013_dwg = 60 (New)
        ac2013_dxf = 61 (New)
        ac2013_Template = 62 (New)
        acNative = 60 (Changed)

New Enums:
AcPointCloudIntensityStyle
        acIntensityGrayscale = 0
        acIntensityRainbow = 1
        acIntensityRed = 2
        acIntensityGreen = 3
        acIntensityBlue = 4
        acIntensityEditableFlag = 5
AcPointCloudColorType
        acTrueColor = 0
        acByColor = 1

Changed Classes:
IAcad3DSolid
        CheckInterference - Method (Added solid interfere parameter)
IAcadDynamicBlockReferenceProperty (Changed)
        show - Property (Renamed, previously Show)
IAcadEntity
        EntityTransparency - Property (New)
IAcadHatch
        BackgroundColor - Property (New)
IAcadLoftedSurface
        EndSmoothContinuity - Property (New)
        EndSmoothMagnitude - Property (New)
        Periodic - Property
        StartSmoothContinuity - Property (New)
        StartSmoothMagnitude - Property (New)
IAcadPointCloud
        Height - Property (New)
        IntensityColorScheme - Property (New)
        Length - Property (New)
        Name - Property (New)
        Path - Property (New)
        ShowClipped - Property (New)
        ShowIntensity - Property (New)
        Width - Property (New)
IAcadPreferencesFiles
        ActiveInvProject - Property (New)
IAcadRasterImage
        transparency - Property (Renamed, previously Transparency)
IAcadSpline
        Closed2 - Property (New)
        Degree2 - Property (New)
        KnotParameterization - Property (New)
        SplineFrame - Property (New)
        SplineMethod - Property (New)
IAcadSurface
        EdgeExtensionDistances - Property (New)
        MaintainAssociativity - Property (New)
        ShowAssociativity - Property (New)
        SurfTrimAssociativity - Property (New)
        WireframeType - Property (New)

Removed Classes:
Classes were merged with the class in which they were derived in most cases (ie. IAcadEntity2 -> IAcadEntity)
IAcad3DFace2
IAcad3DPolyline2
IAcad3DSolid2
IAcadArc2
IAcadAttribute2
IAcadBlockReference2
IAcadCircle2
IAcadDim3PointAngular2
IAcadDimAligned2
IAcadDimAngular2
IAcadDimArcLength2
IAcadDimDiametric2
IAcadDimOrdinate2
IAcadDimRadial2
IAcadDimRadialLarge2
IAcadDimRotated2
IAcadEllipse2
IAcadEntity2
IAcadExternalReference2
IAcadExtrudedSurface2
IAcadExtrudedSurface3
IAcadHatch2
IAcadHelix2
IAcadLine2
IAcadLeader2
IAcadLoftedSurface2
IAcadLoftedSurface3
IAcadLWPolyline2
IAcadMLeader2
IAcadMText2
IAcadNurbSurface2
IAcadOle2
IAcadPlaneSurface2
IAcadPlaneSurface3
IAcadPoint2
IAcadPolyfaceMesh2
IAcadPolygonMesh2
IAcadPolyline2
IAcadPViewport2
IAcadRay2
IAcadRasterImage2
IAcadRegion2
IAcadRevolvedSurface2
IAcadRevolvedSurface3
IAcadShape2
IAcadSolid2
IAcadSpline2
IAcadSurface2
IAcadSurface3
IAcadSweptSurface2
IAcadSweptSurface3
IAcadSubDMesh2
IAcadTable2
IAcadText2
IAcadTolerance2
IAcadTrace2
IAcadXline2
IAcadWipeout2

Sincerely,
  Lee

Handling Drawing (DWG) File Format Changes with AutoCAD

AutoCAD over the past 10+ releases has been seeing a new drawing (DWG) file format change every three releases. The file format changes are done to introduce new features and optimizations.  When working with clients or departments that use a different release of AutoCAD than you, there are a number of options that you can use to make sure you can share DWG files with ease.

The following table outlines which file format you need to use when exchanging drawings with users not using AutoCAD 2013.

AutoCAD Drawing Format	AutoCAD Releases
AutoCAD 2010	AutoCAD 2010 through 2012
AutoCAD 2007	AutoCAD 2007 through 2009
AutoCAD 2004	AutoCAD 2004 through 2006
AutoCAD 2000	AutoCAD 2000 through 2002
AutoCAD R14	AutoCAD R14
AutoCAD R12 DXF	AutoCAD R12 and R13

The following outlines several options that you can use to ease the sharing of DWG files when having to work with multiple releases of AutoCAD and different drawing file formats:

• Set the Default Save Format - In the Options dialog box, Open and Save tab, you can specify the default file format that is used when saving a drawing with the SAVE, SAVEAS, and QSAVE commands. The WBLOCK or REFEDIT commands are not affected by changing the default file format option, you will need to open and resave the drawing files that are created or edited to the desired file format as they only save a drawing to the latest/native file format.
• DWGCONVERT Command - Allows you to batch save selected drawing files to a different file format.  If a drawing has dependencies on external drawing files, each file does not need to be added individually but does not gather up all dependency files related to the selected drawings like the ETRAMNSMIT command.  Each external dependent drawing file is also saved to the specified file format.
  
• ETRANSMIT Command - Allows you to batch save selected drawing files to a different file format and gather all related dependency files. If a drawing has dependencies on external drawing files, each file does not need to be added individually.  Each external dependent drawing file is also saved to the specifiedfile format.
  
• DWG TrueView - Stand-alone application that allows you to view and save drawing files to different releases.  This can be very helpful, if you get drawing files that are saved to the AutoCAD 2013 format but you are using AutoCAD 2012 or earlier. (http://www.autodesk.com/trueview)
  
• AutoCAD WS Website - Website that allows you to view and markup drawings online.  After you upload a drawing file, it can be downloaded back to a local drive.  During the dowload process, you can choose the drawing file format to save the drawing as. (http://www.autocadws.com)
  
• ScriptPro - A utility that allows you to run a script (SCR) file against a set of drawings.  The script file can save the drawing file and mater other needed changes to the drawing file while it is open. (http://usa.autodesk.com/adsk/servlet/item?siteID=123112&id=4091678&linkID=9240618 and http://labs.autodesk.com/utilities/ADN_plugins/catalog/)

Sincerely,
  Lee

Command Database Updated for AutoCAD 2013

I have finished updating my online Command database to include the changes that were introduced with AutoCAD 2013 and included the changes made to AutoCAD 2012.  The online Command database displays:

• Commands in AutoCAD 2004 through AutoCAD 2013.
• Command aliases for commands in AutoCAD 2013.
• Denotes which commands can be started transparently.
• Denotes which commands are part of Express Tools.
• Link to the AutoCAD 2013 help has been added for each command. This link is autogenerated based on command name, and might not work for each command due to the nature of not all commands being documented or the topic file not matching the actual command name.

An offline version of the database can be downloaded from the website as well.  The offline PDF contains the commands from AutoCAD R12 through AutoCAD 2010.  An updated version of the offline PDF will be made available at a later date.

The Command database can be found at:
    http://www.hyperpics.com/commands/

NOTE: The System Variable database updates are in progress yet.

Sincerely,
  Lee

Plotting and Creating Page Setups with AutoLISP

Plotting is a key step in communicating your design with non-AutoCAD users unless you are using AutoCAD WS or another way of hosting your designs for others to see.  While many users go straight to the PLOT command and never bother with page setups, page setups can make plotting a drawing much more consistent and easier if you need to plot your designs at different sizes or formats.  One reason to plot the same layout or design at different sizes might be for a check plot and the other to a specific scale.

Note: This article does not work for those using AutoCAD for Mac because it does not support ActiveX.

The following demonstrates how to plot a layout using a PC3 file.  It first checks to see if a PC3 file is assigned to the current layout for plotting, and if not it assigns the DWF6 ePlot.pc3 file as the current plot device.  Using this same approach, you could plot all layouts in a drawing to PDF or DWF files without changing the current plot configuration, much like the way the PUBLISH command works.

(vl-load-com)
(defun c:QDWF( / doc)
    ;; Get the current drawing
    (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))

    ;; Plot the current layout
    (vla-PlotToDevice (vla-get-Plot doc) "DWF6 ePlot.pc3")
  (princ)
)

The vla-PlotToDevice function above is passed a valid PC3 file, but if you do not pass a PC3 file to the method it will use the plot device assigned to the layout which can be accessed with the vla-get-ConfigName function.

Note: The vla-PlotToDevice function will start plotting in the background or foreground based on the current value of the BACKGROUNDPLOT system variable.

Now that you see how to plot a single layout, you can plot multiple layouts using the vla-SetLayoutsToPlot function.

(defun c:PLOTALL( / doc)
    ;; Get the current drawing
    (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))

    (setq lstLayouts nil
          arSize 0)

    (vlax-for layout (vla-get-layouts doc)
        ;; Check to see if a plot device is assigned to the layout, if not it will not be plotted
        (if (and
                (/= (strcase (vla-get-ConfigName layout)) "NONE")
                (= (vla-get-ModelType layout) :vlax-false)
            )
            (progn
                (if (= lstLayouts nil)
                    (setq lstLayouts (list (vla-get-Name layout)))
                    (setq lstLayouts (append lstLayouts (vla-get-Name layout)))
                )
            )
        )
    )

    ;; Create an array for all the layouts to be plotted
    (setq arLayouts (vlax-make-safearray vlax-vbString (cons 0 (1- (length lstLayouts)))))

    ;; Add the layout names to the array
    (foreach item lstLayouts
        (progn
            (vlax-safearray-put-element arLayouts arSize item)
            (setq arSize (1+ arSize))
        )
    )

    ;; Plot the layout to the device
    (vla-SetLayoutsToPlot (vla-get-Plot doc) arLayouts)
    (vla-PlotToDevice (vla-get-Plot doc))

  (princ)
)

The following demonstrates how to create a named page setup, and then assign it to the current layout.

(defun c:CustomPageSetup()
    ;; Get the current drawing
    (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))

    ;; Get the PlotConfigurations collection
    (setq plotCfgs (vla-get-PlotConfigurations doc))

    ;; Check to see if the pagesetup already exists
    (setq plotCfg (vl-catch-all-apply 'vla-Item (list plotCfgs "MYPAGESETUP")))

    ;; If the page setup exists, the variable will be of type VLA-OBJECT
    (if (/= (type plotCfg) 'VLA-OBJECT)
        ;; Create a page setup for model or paper space accordingly
        (if (= (getvar "TILEMODE") 0) 
            (setq plotCfg (vla-Add plotCfgs "MYPAGESETUP" :vlax-false))
            (setq plotCfg (vla-Add plotCfgs "MYPAGESETUP" :vlax-true))
        )
    )

    ;;(vla-put-Name plotCfg "MYPAGESETUP")
    (vla-RefreshPlotDeviceInfo plotCfg)
 
    ;; Set the plot device
    (vla-put-ConfigName plotCfg "DWF6 ePlot.pc3")

    ;; Set the paper size
    (vla-put-CanonicalMediaName plotCfg "ANSI_C_(22.00_x_17.00_Inches)")

    ;; Set the plot units (inches, millimeters, pixels)
    (vla-put-PaperUnits plotCfg acInches)

    ;; Set what to plot
    ;; - If using acView, set the ViewToPlot property
    ;; - If using acWindow, call GetWindowToPlot
    (if (= (getvar "TILEMODE") 0)
        (progn
            (vla-put-PlotType plotCfg acLayout)

            ;; Set scale
            (vla-put-UseStandardScale plotCfg :vlax-true)
            (vla-put-StandardScale plotCfg ac1_1)         
        )
        (progn
            (vla-put-PlotType plotCfg acExtents)

            ;; Set scale
            (vla-put-UseStandardScale plotCfg :vlax-true)
            (vla-put-StandardScale plotCfg acScaleToFit)
         
            ;; Center the plot on the page
            (vla-put-CenterPlot plotCfg :vlax-true)
        )
    )

    ;; Hide paperspace objects
    (vla-put-PlotHidden plotCfg :vlax-false)

    ;; Set the plot origin
    (setq origin (vlax-make-safearray vlax-vbDouble '(0 . 1)))
    (vlax-safearray-fill origin (list 0.5 0.5))
    (vla-put-PlotOrigin plotCfg origin)

    ;; Set the plot rotation
    (vla-put-PlotRotation plotCfg ac0degrees)

    ;; Set viewport plot behavior
    (vla-put-PlotViewportBorders plotCfg :vlax-false)
    (vla-put-PlotViewportsFirst plotCfg :vlax-true)

    ;; Set lineweight behavior
    (vla-put-PlotWithLineweights plotCfg :vlax-true)
    (vla-put-ScaleLineweights plotCfg :vlax-true)

    ;; Set plot styles behavior
    (vla-put-PlotWithPlotStyles plotCfg :vlax-true)
    (vla-put-ShowPlotStyles plotCfg :vlax-true)

    (if (= (getvar "PSTYLEMODE") 0)
        (vla-put-StyleSheet plotCfg "acad.stb")
        (vla-put-StyleSheet plotCfg "acad.ctb")
    )

    ;; Assign the page setup to the current layout
    (vla-CopyFrom (vla-get-ActiveLayout doc) plotCfg)
)

Hope you enjoyed the sample code.

Sincerely,
  Lee

Autodesk Announces AutoCAD 2011 and Other Products

Autodesk has just released AutoCAD 2011, AutoCAD 2011-based products, and other 2011 products today. I will have more information on the changes to AutoCAD 2011 on my Website over the next few weeks.  For more information on the latest product announcements, visit http://www.autodesk.com.

System Variables List Updated for AutoCAD R12 through AutoCAD 2009

I have updated the System Variables list on my website to now list all of the new or changed system variables in AutoCAD 2009.  Like the Commands list, it is really amazing to see all the system variables back to AutoCAD R12 with those that are still in AutoCAD 2009 today and the ones that have been added since then.  Enjoy the list, there is still some work to do yet but for the most part it is complete.  The work that is outstanding is the description and available values of the system variables, all descriptions should be updated in the upcoming weeks.

System Variables List - http://www.hyperpics.com/system_variables

For more about past versions of AutoCAD, check out Shaan Hurley's Unofficial AutoCAD History Page.

As for the PDF files that are related to each of the Command and System Variables lists, I will start work on those very soon and will post once those have been updated.  If you have any questions or comments, let me know.

Sincerely,
  Lee

Blog Roundup

What happens when you take "1 Part CAD Site" and mix it (not shake it) with "1 Part AutoCAD RSS Feed Aggregator" or for those that know AutoLISP (+ "CAD Site" "AutoCAD RSS Feed Aggregator")?  I'm not sure, but if it was possible to derive a solution from the formula I am sure you would get something close to CADtutor.net.  While I have often visited CADtutor.net it wasn't until recently that I discovered that the site was aggregating many of the commonly visited AutoCAD and CAD related blogs in the industry.  It is a great way to keep up to date on what is happening in the industry as well as learn new tips and tricks about AutoCAD and other programs that you might use.  The link to the AutoCAD RSS Feed page on CADTutor.net is below:

http://www.cadtutor.net/forum/forumdisplay.php?f=38

Michael's Corner is also a great section of CADtutor.net to visit as well.  He has been writing a monthly column on various aspects of AutoCAD since 2003, with the exception of January of 2008 when he spent a few weeks away on vacation when I filled in for him.  Michael is a great guy and is always willing to help AutoCAD users when he can.

Sincerely,
  Lee